## <summary>Network UPS Tools </summary>

########################################
## <summary>
##	All of the rules required to
##	administrate an nut environment.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	Role allowed access.
##	</summary>
## </param>
## <rolecap/>
#
interface(`nut_admin',`
	gen_require(`
		attribute nut_domain;
		type nut_initrc_exec_t, nut_runtime_t, nut_conf_t;
	')

	allow $1 nut_domain:process { ptrace signal_perms };
	ps_process_pattern($1, nut_domain)

	init_startstop_service($1, $2, nut_domain, nut_initrc_exec_t)

	files_search_etc($1)
	admin_pattern($1, nut_conf_t)

	files_search_runtime($1)
	admin_pattern($1, nut_runtime_t)
')
