## <summary>Cluster File System binary, daemon and command line.</summary>

########################################
## <summary>
##	All of the rules required to
##	administrate an glusterfs environment.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	Role allowed access.
##	</summary>
## </param>
## <rolecap/>
#
interface(`glusterfs_admin',`
	gen_require(`
		type glusterd_t, glusterd_initrc_exec_t, glusterd_log_t;
		type glusterd_tmp_t, glusterd_conf_t, glusterd_var_lib_t;
		type glusterd_runtime_t;
	')

	init_startstop_service($1, $2, glusterd_t, glusterd_initrc_exec_t)

	allow $1 glusterd_t:process { ptrace signal_perms };
	ps_process_pattern($1, glusterd_t)

	files_search_etc($1)
	admin_pattern($1, glusterd_conf_t)

	logging_search_logs($1)
	admin_pattern($1, glusterd_log_t)

	files_search_tmp($1)
	admin_pattern($1, glusterd_tmp_t)

	files_search_var_lib($1)
	admin_pattern($1, glusterd_var_lib_t)

	files_search_runtime($1)
	admin_pattern($1, glusterd_runtime_t)
')
