## <summary>On-line manual database.</summary>

########################################
## <summary>
##	Execute the mandb program in
##	the mandb domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed to transition.
##	</summary>
## </param>
#
interface(`mandb_domtrans',`
	gen_require(`
		type mandb_t, mandb_exec_t;
	')

	corecmd_search_bin($1)
	domtrans_pattern($1, mandb_exec_t, mandb_t)
')

########################################
## <summary>
##	Execute mandb in the mandb
##	domain, and allow the specified
##	role the mandb domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed to transition.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	Role allowed access.
##	</summary>
## </param>
#
interface(`mandb_run',`
	gen_require(`
		attribute_role mandb_roles;
	')

	mandb_domtrans($1)
	roleattribute $2 mandb_roles;
')

########################################
## <summary>
##	All of the rules required to
##	administrate an mandb environment.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	Role allowed access.
##	</summary>
## </param>
## <rolecap/>
#
interface(`mandb_admin',`
	gen_require(`
		type mandb_t;
	')

	admin_process_pattern($1, mandb_t)

	mandb_run($1, $2)
')
