## <summary> Tools to send and receive short messages through GSM modems or mobile phones.</summary>

########################################
## <summary>
##	All of the rules required to
##	administrate an smstools environment.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	Role allowed access.
##	</summary>
## </param>
## <rolecap/>
#
interface(`smstools_admin',`
	gen_require(`
		type smsd_t, smsd_initrc_exec_t, smsd_conf_t;
		type smsd_log_t, smsd_var_lib_t, smsd_runtime_t;
		type smsd_spool_t;
	')

	allow $1 smsd_t:process { ptrace signal_perms };
	ps_process_pattern($1, smsd_t)

	init_startstop_service($1, $2, smsd_t, smsd_initrc_exec_t)

	files_search_etc($1)
	admin_pattern($1, smsd_conf_t)

	files_search_var_lib($1)
	admin_pattern($1, smsd_var_lib_t)

	files_search_spool($1)
	admin_pattern($1, smsd_spool_t)

	files_search_runtime($1)
	admin_pattern($1, smsd_runtime_t)

	logging_search_logs($1)
	admin_pattern($1, smsd_log_t)
')
