## <summary>Rshd, rlogind, and telnetd.</summary>

########################################
## <summary>
##	Domain transition to the remote login domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed to transition.
##	</summary>
## </param>
#
interface(`remotelogin_domtrans',`
	gen_require(`
		type remote_login_t;
	')

	corecmd_search_bin($1)
	auth_domtrans_login_program($1, remote_login_t)
')

########################################
## <summary>
##	Send generic signals to remote login.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`remotelogin_signal',`
	gen_require(`
		type remote_login_t;
	')

	allow $1 remote_login_t:process signal;
')

########################################
## <summary>
##	Create, read, write, and delete
##	remote login temporary content.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`remotelogin_manage_tmp_content',`
	gen_require(`
		type remote_login_tmp_t;
	')

	files_search_tmp($1)
	allow $1 remote_login_tmp_t:dir manage_dir_perms;
	allow $1 remote_login_tmp_t:file manage_file_perms;
')

########################################
## <summary>
##	Relabel remote login temporary content.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`remotelogin_relabel_tmp_content',`
	gen_require(`
		type remote_login_tmp_t;
	')

	files_search_tmp($1)
	allow $1 remote_login_tmp_t:dir relabel_dir_perms;
	allow $1 remote_login_tmp_t:file relabel_file_perms;
')
